 |
4.9.3 Mappatura
delle Texture
Sappiamo come unire colori, pigmenti
e normali e stiamo probabilmente pensando alle finiture. E intere texture ?
Tutti e due possono essere trattati in un unico paragrafo. Mentre non c'è
una mappatura delle finiture di per sé, ci sono le mappature di
texture e quindi possiamo adattarle facilmente a svolgere il ruolo di mappature
per la finitura utilizzando gli stessi pigmenti e/o normali in ciascuno
dei componenti della mappa. Questo è un esempio. Eliminiamo i pigmenti
che avevamo dichiarato prima ed aggiungiamo il testo seguente :
#declare Texture1 = texture {
pigment { Grey }
finish { reflection 1 }
}
#declare Texture2 = texture {
pigment { Grey }
finish { reflection 0 }
}
cylinder { <-2, 5, -2>, <-2, -5, -2>, 1
pigment { Blue }
}
plane { -z, 0
rotate y * 30
texture {
gradient y
texture_map {
[ 0.0 Texture1 ]
[ 0.4 Texture1 ]
[ 0.6 Texture2 ]
[ 1.0 Texture2 ]
}
scale 2
}
}
|
Fig. 159-Mappatura di texture
Ora, cosa abbiamo ottenuto ? Il piano cambia continuamente tra due texture, identiche in tutto tranne che nella finitura. Quando renderizziamo questa scena, il cilindro si riflette su parte del piano e su parte no. Con qualche piccolo adattamento, si potrebbe usare questo metodo con ogni pattern ed in ogni modo creativo, sia che vogliamo fornire finiture diverse a parti diverse dell'oggetto, come in questo caso, sia che vogliamo alternare texture completamente diverse. Ci si potrebbe chiedere : se esiste la mappatura delle texture, perché abbiamo bisogno di mappature dei pigmenti e delle normali ? Ottima domanda. La risposta è : velocità di calcolo. Se usiamo una mappatura di texture, per ogni punto intermedio tra due elementi della mappa, POV-Ray deve fare calcoli per ogni elemento della texture e quindi calcolare una media pesata per determinare il corretto colore di quel punto. Usando solo una mappatura di pigmenti (o di normali) si riduce il numero totale di operazioni e la nostra texture viene renderizzata un po' più velocemente. Come regola generale, si usano mappature di pigmenti e di normali dove si può e mappature di texture dove è richiesta una flessibilità superiore.
 |
 |
 |