4.6.2        La Luce Puntiforme.


Una sorgente di luce puntiforme è esattamente ciò che il suo nome indica. Questa luce non ha dimensioni, è invisibile ed illumina tutto nella scena in maniera uguale, non importa quanto lontano dalla luce (ma questo comportamento può essere cambiato). Questa è la luce più semplice. Ci sono solo due parametri importanti, la posizione ed il colore. Creiamo una semplice scena ed inseriamoci una luce puntiforme. Creiamo un nuovo file e lo chiamiamo litedemo.pov. Lo editiamo come segue :

#include "colors.inc"
#include "textures.inc"

camera {
location <-4, 3, -9>
look_at <0, 0, 0>
angle 48
}

Aggiungiamo i seguenti, semplici oggetti :

plane { y, -1
texture {
pigment {
checker
color rgb<0.5, 0, 0>
color rgb<0, 0.5, 0.5>
}
finish {
diffuse 0.4
ambient 0.2
phong 1
phong_size 100
reflection 0.25
}
}
}

torus { 1.5, 0.5
texture { Brown_Agate }
rotate <90, 160, 0>
translate <-1, 1, 3>
}

box { <-1, -1, -1>, <1, 1, 1>
texture { DMFLightOak }
translate <2, 0, 2.3>
}

cone { <0,1,0>, 0, <0,0,0>, 1
texture { PinkAlabaster }
scale <1, 3, 1>
translate <-2, -1, -1>
}

sphere { <0,0,0>,1
texture { Sapphire_Agate }
translate <1.5, 0, -2>
}

E ora, una luce puntiforme :

light_source {
<2, 10, -3>
color White
}

Fig. 72-Illuminazione della luce puntiforme

Renderizziamo questa scena a 200x150 -A e vediamo che gli oggetti sono chiaramente visibili, con ombre ben nette. I lati degli oggetti curvi più vicini alla luce sono i più chiari, mentre le zone rivolte dalla parte opposta alla luce, sono le più scure. Notiamo anche che il piano a scacchiera è illuminato uniformemente fino all'orizzonte. Questo ci permette di vedere il piano, ma non è molto realistico.